Σύγχρονες γλώσσες προγραμματισμού

Οι υπολογιστές και ο προγραμματισμός τους

Καλώς ήρθατε

Σύγχρονες γλώσσες προγραμματισμού H/Y

• Διομήδης Σπινέλλης <dds@aueb.gr (mailto:dds@aueb.gr)>
• Προγραμματισμός σε Visual Basic
• Στοιχεία Java
• 32 ώρες θεωρία

Τι περιλαμβάνει το μάθημα

1. Οι υπολογιστές και ο προγραμματισμός τους
2. Το περιβάλλον της Visual Basic
3. Υπολογισμοί με μεταβλητές, είσοδος και έξοδος
4. Τελεστές σύγκρισης, λογικής και επαναλήψεις
5. Προγραμματισμός με συμβολοσειρές, αποφάσεις
6. Πρόσθετες δομές ελέγχου: select, on error
7. Ορισμός συναρτήσεων και διαδικασιών
8. Συναρτήσεις και διαδικασίες της Visual Basic
9. Βασικές αρχές αντικειμενοστρεφούς προγραμματισμού
10. Διεπαφή χρήστη
11. Ιδιότητες και μέθοδοι για υλοποίηση διεπαφών
12. Μεταγλώττιση και εγκατάσταση προγραμμάτων
13. Διαχείριση δεδομένων: σύνδεση με βάσεις δεδομένων, συλλογές αντικειμένων, πίνακες, αρχεία κειμένου, πολυμέσα
14. Προγραμματισμός με εξαρτήματα, σύνδεση με άλλες εφαρμογές
15. Προγραμματισμός στο διαδίκτυο
16. Από τη Visual Basic στη Java

Τρόπος διδασκαλίας

• Συμμετοχή
• Ερωτήσεις
• Ασκήσεις

Οι σημειώσεις

• Δε θα μοιράζονται
• Προσβάσιμες από το WWW:http://www.eltrun.aueb.gr/dds/mlang (http://www.eltrun.aueb.gr/dds/mlang)
• Δεν καλύπτονται από τα βιβλία
• Δεν καλύπτουν όλο το μάθημα
• Υπάρχουν και σε μορφή κατάλληλη για εκτύπωση

Υλικό και λογισμικό

• Υλικό (hardware) καλούμε τα φυσικά στοιχεία του υπολογιστή.
• Λογισμικό (software) καλούμε το σύνολο των προγραμμάτων που χρησιμοποιεί ο υπολογιστής.
• Τα προγράμματα είναι αποθηκευμένες οδηγίες που εκτελούνται από το υλικό.

Ιστορική ανασκόπηση

• Προγραμματισμός με διακόπτες
• Γλώσσα μηχανής
• Συμβολική γλώσσα
• Fortran
• Algol, C, Pascal, Modula-2
• Lisp, Simula, Prolog, ML
• Smalltalk, C++, Java
• Visual Basic, TCL/TK, Perl

Χαρακτηριστικές αλγοριθμικές γλώσσες

• Fortran, Fortran 9X
• Cobol
• Algol-60
• Basic
• PL/I
• Pascal, Modula-2, Oberon
• C
• Ada
• Smalltalk
• C++
• Awk, Perl, Tcl/Tk
• Java
• Python

Χαρακτηριστικές δηλωτικές γλώσσες

Γλώσσες βασισμένες στη λογική

• Prolog
• CHIP

Γλώσσες βασισμένες σε συναρτήσεις

• Lisp
• Scheme
• Haskell
• ML

Βασικά γλωσσικά εργαλεία

Προετοιμαστής/Διορθωτής (Editor)

Επιτρέπει τη συγγραφή και την αλλαγή του προγράμματος.

Προεπεξεργαστής (Preprocessor)

Επεξεργάζεται το πρόγραμμα εκτελώντας απλούς συμβολικούς μετασχηματισμούς και παράγει ένα αντίστοιχο πρόγραμμα. Χρησιμοποιείται σε συμβολικές γλώσσες, τη Fortran (Ratfor), τη C, και τη C++.

Συμβολομεταφραστής (Assembler)

Μετατρέπει τη συμβολική γλώσσα του επεξεργαστή σε γλώσσα μηχανής.

Μεταγλωττιστής (Compiler)

Μεταφράζει μια γλώσσα υψηλού επιπέδου σε γλώσσα επιπέδου μηχανής.

Διερμηνευτής (Interpreter)

Εκτελεί άμεσα ένα πρόγραμμα σε γλώσσα υψηλού επιπέδου.

Συνδέτης (Linker)

Συρράφει τμήματα ενός προγράμματος που έχουν μεταγλωττιστεί ξεχωριστά σε ένα συνεχές πρόγραμμα.

Φορτωτής (Loader)

Φορτώνει το πρόγραμμα στη μνήμη του επεξεργαστή διορθώνοντας αναφορές σε σχετικές θέσεις μνήμης. Συνήθως τμήμα του λειτουργικού συστήματος.

Αποσφαλματωτής (Debuger)

Επιτρέπει την εκτέλεση του προγράμματος βήμα-βήμα, την εξέταση και αλλαγή μεταβλητών του και γενικά ενέργειες που αποσκοπούν στην ανίχνευση λαθών που μπορεί να περιέχει το πρόγραμμα.

Διερμηνευτής (Interpreter)

Εκτελεί απευθείας τις εντολές του προγράμματος χωρίς ενδιάμεσο στάδιο μεταγλώττισης.

Η διεργασία του προγραμματισμού

• Προσδιορισμός απαιτήσεων
• Ανάλυση / σχεδίαση
• Συγγραφή σε ψευδοκώδικα
• Συγγραφή στη γλώσσα προγραμματισμού
• Μεταγλώττιση
• Εκτέλεση
• Έλεγχος / επαλήθευση
• Αποσφαλμάτωση

Βιβλιογραφία

• Michael Halvorson Visual Basic 6 Βήμα προς βήμα. Εκδόσεις Κλειδάριθμος, Αθήνα.

• Alfred V. Aho, Ravi Sethi, and Jeffrey D. Ullman. Compilers, Principles, Techniques, and Tools. Addison-Wesley, 1985.

• Alfred V. Aho, Brian W. Kernighan, and Peter J. Weinberger. The AWK Programming Language. Addison-Wesley, 1988.

• J.W. Backus, F.L. Bauer, J.Green, C.Katz, J.McCarthy, P. Naur, A.J.Perlis, H. Rutishauser, K. Samuelson, B. Vauquois, J.H. Wegstein, A. van Vinjgaarden, and M. Woodger. Revised report on the algorthmic language ALGOL 60. IFIP, 1960.

• David Boctor. Microsoft Office 2000 Visual Basic Fundamentals. Microsoft Press, Redmond, WA, USA, 1999.

• Jean D. Ichbiah et al. Reference Manual for the Ada Programming Language, ANSI/MIL-STD-1815 A-1983. Castle House Publication Ltd., 1983.

• David Flanagan. Java in a Nutshell. O'Reilly and Associates, Sebastopol, CA, USA, 1997.

• Kathleen Jensen and Niklaus Wirth. PASCAL User Manual and Report. Springer Verlag, second edition, 1975.

• Brian W. Kernighan and Dennis M. Ritchie. The C Programming Language, pages ix–4. Prentice-Hall, second edition, 1988.

• Brian W. Kernighan. Why Pascal is not my favorite programming language. Technical Report 100, Bell Laboratories, Murray Hill, New Jersey 07974, July 1981.

• Günther Lamprecht. Introduction to SIMULA-67. Friedr. Vieweg & Sohn, Braunschweig, Wiesbaden, Germany, 1981.

• Mark Lutz. Programming Python. O'Reilly and Associates, 1996.

• Charles Petzold. Code: The Hidden Language of Computer Hardware and Software. Microsoft Press, Redmond, Washington, USA, 1999.

• Martin Richards and Colin Whitby-Strevens. BCPL — The Language and its Compiler. Cambridge University Press, 1979.

• Michael L. Scott. Programming Language Pragmatics. Morgan Kaufmann Publishers, 1999.

• Ravi Sethi. Programming Languages: Concepts and Constructs. Addison-Wesley, 1989.

• Bjarne Stroustrup. The C++ Programming Language. Addison-Wesley, second edition, 1991.

• R. D. Tennent. Princliples of Programming Languages. Prentice Hall, 1981.

• Larry Wall and Randal L. Schwartz. Programming Perl. O'Reilly and Associates, Sebastopol, CA, USA, 1990.

• Richard L. Wexelblat. Maxims for malfeasant designers, or how to design languages to make programming as difficult as possible. In Proceedings of the 2nd International Conference on Software Engineering, pages 331–336, San Fransisco, CA, USA, October 1976. IEEE Computer Society Press.

Το περιβάλλον της Visual Basic

Το περιβάλλον της Visual Basic

• Στο κέντρο γράφεται ο κώδικας της εφαρμογής
• Αριστερά επιλέγονται τα όργανα που τοποθετούνται στη φόρμα.
• Άνω δεξιά μπορεί κανείς να επιλέξει τις φόρμες και τα αρθρώματα της εφαρμογής.
• Με την πάνω γραμμή εργαλείων μπορεί κανείς μεταξύ άλλων να ξεκινήσει και να σταματήσει την εφαρμογή.

Πως γράφουμε απλά προγράμματα

1. Όταν ξεκινήσει η Visual Basic επιλέγουμε τη δημιουργία "Standard EXE"
   
2. Με το πλήκτρο F4 κλείνουμε το παράθυρο με τη φόρμα που εμφανίζεται.
3. Από το μενού Project επιλέγουμε Add module και από τις επιλογές που εμφανίζονται "Module".
   
4. Στο παράθυρο που εμφανίζεται στο Project - Properties, στην κατηφορία General επιλέγουμε ως Startup Object "Sub Main".
   

Το πρώτο μου πρόγραμμα

Sub main()
    MsgBox "hello, world"
End Sub

Μορφή του προγράμματος

• Η γραμμή "Sub Main" ορίζει μια διαδικασία (procedure), στη δική μας περίπτωση το σημείο απ' όπου ξεκινάει το πρόγραμμα.
• MsgBox
• Το κείμενο μέσα στα εισαγωγικά είναι μια συμβολοσειρά (string).
• End Sub
• Κάθε γραμμή περιέχει μια εντολή
• Μπορούμε να προσθέσουμε δικά μας σχόλια (comments) αν αρχίσουμε ή συνεχίσουμε μια γραμμή με μονά εισαγωγικά.

Υπολογισμοί με μεταβλητές, είσοδος και έξοδος

Σταθερές

• Η συμβολοσειρά "hello, world" την οποία είδαμε στην προηγούμενη ενότητα είναι μια σταθερά (constant) της Visual Basic.
• Οι σταθερές αυτές χρησιμοποιούνται συχνά για να παραστήσουν μηνύματα προς το χρήστη (π.χ. "Παρακαλώ βάλτε την κάρτα σας στην υποδοχή") ή και μεταξύ υπολογιστών (π.χ. "RCPT TO: dspin@aegean.gr").
• Ένα άλλο είδος σταθερών είναι αυτές που παριστάνουν αριθμητικές τιμές (π.χ. 42 ή 3.1415927).
• Στη Visual Basic ξεχωρίζουμε της ακέραιες (integer) σταθερές (π.χ. 42, 123456, -3) και τις σταθερές που παριστάνουν αριθμούς κινητής υποδιαστολής (floating point numbers) (π.χ. 3.1415827, -2.0, 6.023e-23).

Εκτύπωση τιμών

• Για να εμφανίσουμε αριθμητικές τιμές στην οθόνη πρέπει να τις μετατρέψουμε σε συμβολοσειρά και να τις "προσθέσουμε" στην υπόλοιπη συμβολοσειρά που θέλουμε να εμφανίσουμε. Τη μετατροπή της αριθμητικής τιμής σε συμβολοσειρά εκτελεί η συνάρτηση (function) Str. Παράδειγμα:

  	MsgBox "Τα γραπτά βαθμολογούνται με βαθμούς από το " + str(0) + " μέχρι το " + str(10)
  

Απλές πράξεις

• Για τον υπολογισμό μιας τιμής, πρώτα εκτελούνται οι πράξεις ανάμεσα στον τελεστή ^, μετά ανάμεσα στους τελεστές * / mod και μετά οι πράξεις ανάμεσα στους τελεστές + -.
• Η παραπάνω σειρά μπορεί να μεταβληθεί με τη χρήση παρενθέσεων.

Παραδείγματα

• MsgBox "ένα συν ένα = " + Str(1 + 1)
• MsgBox "Το εμβαδό του δωματίου είναι " + Str(3 * 5) + " τετραγωνικά μέτρα."
• MsgBox Str(36.7) + " βαθμοί Celsius = " + Str(32 + 9.0 / 5.0 * 36.7) + " βαθμοί Fahrenheit."
• MsgBox Str(1 + 2 * 3) 'Τυπώνει 7
• MsgBox Str((1 + 2) * 3) ' Τυπώνει 9

Μεταβλητές

• Οι αριθμητικές τιμές μπορούν να αποθηκευτούν σε μεταβλητές (variables)
• Το όνομα μιας μεταβλητής πρέπει να αρχίζει με έναν λατινικό αλφαβητικό χαρακτήρα και να ακολουθείται από λατινικού αλφαβητικούς χαρακτήρες ή/και ψηφία. Παράδειγμα: Temperature, X1, Y1, X2, Y2, Total
• Τα ονόματα των μεταβλητών δεν πρέπει να ταυτίζονται με δεσμευμένες λέξεις (reserved words) της Visual Basic (Sub, MsgBox, End, κ.λπ.).
• Ο ορισμός τους γίνεται γράφοντας τη λέξη Dim, το όνομα της μεταβλητής και τον τύπο της μεταβλητής (integer για ακέραιες τιμές, double για τιμές κινητής υποδιαστολής, string για συμβολοσειρές).
• Μπορούμε να ορίσουμε πολλές μεταβλητές ίδιου τύπου χωρίζοντάς τις με ",". Παράδειγμα:

  	Dim Faces as Integer
  	Dim X As Double, Y As Double
  

• Για να δώσουμε μια τιμή σε μια μεταβλητή χρησιμοποιούμε τη σύνταξη:

  	μεταβλητή = τιμή
  

  για παράδειγμα:

  	Faces = 2 * 8 + 12
  

• Στη συνέχεια μπορούμε να χρησιμοποιούμε την τιμή της μεταβλητής όπως και οποιοδήποτε άλλη σταθερά. Παράδειγμα:

   
  Sub Main()
  	Dim Faces As Integer
  	Dim Len As Double
  
  	Len = 12.5;
  	Faces = 6;
  	MsgBox "Επιφάνεια = " + Str(Len * Len * Faces)
  End Sub
  

Είσοδος στοιχείων

• Μπορούμε να κάνουμε το πρόγραμμά μας να σταματήσει την εκτέλεσή του για να διαβάσει από το χρήστη κάποιες τιμές. Για παράδειγμα το πρόγραμμα ελέγχου μια μηχανής αυτόματης ανάληψης χρημάτων σταματά την εκτέλεσή του όταν τυπώνει την ερώτηση "Δώστε το ποσό που θέλετε να αναλάβετε" και περιμένει από το χρήστη να γράψει την αντίστοιχη τιμή.
• Η συνάρτηση της Visual Basic InputBox σταματά την εκτέλεση ενός προγράμματος με ένα μήνυμα και περιμένονει ο χρήστης του να πληκτρολογήσει κάποια τιμή. Στη συνέχεια επιστρέφει την τιμή αυτή και μπορούμε να την αναθέσουμε σε μια μεταβλητή. Παράδειγμα:

  Sub main()
      Dim Temperature As Double
      
      Temperature = InputBox("Enter temperature")
      MsgBox "The temperature is " + Str(Temperature)
  End Sub
  

  
• Παρατήρηση: αφού ο χρήστης γράψει την τιμή πρέπει να πατήσει το πλήκτρο ENTER ή να κάνει click στο πλήκτρο OK για να συνεχίσει το πρόγραμμα τη λειτουργία του.

Ασκήσεις

Είσοδος έξοδος και υπολογισμοί

1. Να γράψετε ένα πρόγραμμα που θα διαβάζει από το χρήστη την τιμή ενός προϊόντος με το ΦΠΑ και να τυπώνει την τιμή χωρίς το ΦΠΑ. Παράδειγμα της εκτέλεσης του πρόγραμματος:
   
   

Τελεστές σύγκρισης, λογικής και επαναλήψεις

Τελεστές σύγκρισης

• Για τον υπολογισμό μιας τιμής, πρώτα εκτελούνται οι πράξεις με την παρακάτω σειρά:
  1. ^
  2. * /
  3. mod
  4. + -
  5. = <>. < > <= >=
• Η παραπάνω σειρά μπορεί να μεταβληθεί με τη χρήση παρενθέσεων.
• Το αποτέλεσμα της κάθε σύγκρισης είναι αληθές (True) αν το αποτέλεσμα της σύγκρισης είναι αληθές και ψευδές (False) αν το αποτέλεσμα της σύγκρισης είναι ψευδές.
• Οι τιμές True και False είναι λογικές σταθερές.

Παραδείγματα

MsgBox 1 + 1 = 2	'  Εμφανίζει True
MsgBox 1 > 2		'  Εμφανίζει False
MsgBox 5 <> 5		'  Εμφανίζει False
MsgBox 1 <= 5		'  Εμφανίζει True
MsgBox 1 <= 1		'  Εμφανίζει True
MsgBox 1 <= 0		'  Εμφανίζει False

Βρόχοι με την εντολή do while

• Μπορούμε να επαναλάβουμε την εκτέλεση ορισμένων εντολών με τη δομή ελέγχου (control structure) do while ... loop.
• Αυτή χρησιμοποιείται ως εξής:

  	do while συνθήκη
  		εντολή
  		εντολή
  		...
  	loop
  

• Οι εντολές που ακολουθούν το do while εκτελούνται όσο η συνθήκη είναι αληθής. Παράδειγμα (εμφανίζει στην οθόνη τους αριθμούς από το 0 μέχρι το 4):

  Sub main()
  Dim i As Integer
  
  i = 0
  Do While i < 5
      MsgBox i
      i = i + 1
  Loop
  End Sub
  

• Αν η συνθήκη δεν είναι αληθής όταν εκτελεστεί το do while για πρώτη φορά τότε οι εντολές που περιέχονται σε αυτό δε θα εκτελεστούν.
• Η δομή ελέγχου do while ... loop μπορεί να χρησιμοποιηθεί οπουδήποτε θα μπορούσε και οποιαδήποτε άλλη εντολή (π.χ. η MsgBox) δηλαδή ακόμα και μέσα σε μια άλλη do while. Το παρακάτω παράδειγμα εμφανίζει στην οθόνη την προπαίδεια των αριθμών από το 2 μέχρι το 5.

  Sub main()
  Dim i As Integer
  Dim j As Integer
  
  i = 2
  Do While i <= 5
      j = i
      Do While j <= 5
          MsgBox Str(i) + " * " + Str(j) + " = " + Str(i * j)
          j = j + 1
      Loop
      i = i + 1
  Loop
  End Sub
  

Βρόχοι με την εντολή loop while

• Ορισμένες φορές θέλουμε να ελέγχουμε τη συνθήκη στο τέλος του βρόχου, δηλαδή το περιεχόμενο του βρόχου να εκτελεστεί τουλάχιστον μια φορά. Στις περιπτώσεις αυτές χρησιμοποιούμε τη δομή ελέγχου do ... loop while
• Αυτή χρησιμοποιείται ως εξής:

  	
  	do
  		εντολή
  		εντολή
  		...
  	loop while συνθήκη
  

• Οι εντολές που ακολουθούν το do εκτελούνται μια φορά και συνεχίζουν να εκτελούνται όσο η συνθήκη είναι αληθής.
• Σημαντικό ρόλο έχει αυτή η δομή ελέγχου όταν διαβάζουμε στοιχεία από το χρήστη και θέλουμε να ελέγξουμε την είσοδο για λάθη. Παράδειγμα (θέλουμε ο χρήστης να εισάγει έναν αριθμό μικρότερο του 10):

  Sub main()
      Dim Number As Integer
      Do
          Number = InputBox("Δώστε έναν αριθμό μικρότερο του 10")
      Loop While Number >= 10
      MsgBox "Δώσατε " + Str(Number)
  End Sub
  
  

• Αν η συνθήκη δεν είναι αληθής όταν εκτελεστεί το do για πρώτη φορά τότε οι εντολές που περιέχονται σε αυτό θα εκτελεστούν τουλάχιστον μια φορά.
• Η δομή ελέγχου do loop while μπορεί να χρησιμοποιηθεί οπουδήποτε θα μπορούσε και οποιαδήποτε άλλη εντολή (π.χ. η MsgBox) δηλαδή ακόμα και μέσα σε μια άλλη do while ... loop ή do ... loop while.

Προσδιορισμός της συνθήκης με τη χρήση της Until

• Μερικές φορές είναι πιο φυσικό να εκφράσουμε τη συνθήκη που τερματίζει το βρόχο αντί για τη συνθήκη που πρέπει να είναι αληθής για να εκτελείται ο βρόχος.
• Και οι δύο δομές ελέγχου που είδαμε μπορούν να διατυπωθούν με τη χρήση του προσδιορισμού "Until συνθήκη" αντί για τον προσδιορισμό "While συνθήκη".
• Έτσι, τα παραδείγματα που έχουμε δει μπορούν να γραφτούν και ως εξής:

  Παράδειγμα do while ... loop (εμφανίζει στην οθόνη τους αριθμούς από το 0 μέχρι το 4):

  Sub main()
  Dim i As Integer
  
  i = 0
  Do Until i >= 5
      MsgBox i
      i = i + 1
  Loop
  End Sub
  

  Παράδειγμα do ... loop while (θέλουμε ο χρήστης να εισάγει έναν αριθμό μικρότερο του 10):

  Sub main()
      Dim Number As Integer
      Do
          Number = InputBox("Δώστε έναν αριθμό μικρότερο του 10")
      Loop Until Number < 10
      MsgBox "Δώσατε " + Str(Number)
  End Sub
  

Λογικοί τελεστές

• Τα αποτελέσματα χρήσης των τελεστών παριστάνονται από τους παρακάτω πίνακες τιμών:

  A	B	A And B	A Or B
  False	False	False	False
  False	True	False	True
  True	False	False	True
  True	True	True	True

  A	B	A Xor B	A Eqv B
  False	False	False	True
  False	True	True	False
  True	False	True	False
  True	True	False	True

  A	B	A Imp B
  False	False	True
  False	True	True
  True	False	False
  True	True	True

  A	Not A
  False	True
  True	False

• Η προτεραιότητα υπολογισμού των λογικών τελεστών ορίζεται ως εξής:
  1. Not
  2. And
  3. Or
  4. Xor
  5. Eqv
  6. Imp

Παράδειγμα

    Dim PIN As Integer
    Dim Tries As Integer
    
    Const CorrectPIN = 1234
    Const MaxTries = 4
    
    Tries = 0
    Do
        PIN = InputBox("Πληκτρολογήστε τον κωδικό εισόδου")
        Tries = Tries + 1
    Loop Until PIN = CorrectPIN Or Tries = MaxTries

Λογικές τιμές

• Τα αποτελέσματα των λογικών πράξεων μπορούν να φυλαχτούν σε μεταβλητές τύπου Boolean.
• Οι μεταβλητές αυτές μπορούν να χρησιμοποιηθούν σε εντολές που απαιτούν λογική τιμή ή σε λογικές εκφράσεις.
• Παράδειγμα:

  Dim b as Boolean
  Dim i as integer
  
  i = inputbox("Please give a number less than 10")
  b = i < 10
  if not b then
  	msgbox "Wrong number"
  end if
  

• Οι σταθερές True και False μπορούν να παραστήσουν μέσα στο πρόγραμμα τις αντίστοιχες λογικές τιμές.

Ασκήσεις

Βρόχοι

1. Να γράψετε ένα πρόγραμμα που να υπολογίζει τη συνολική απόδοση μιας κατάθεσης με ετήσιο επιτόκιο που μεταβάλλεται κάθε χρόνο.
   • Στην αρχή το πρόγραμμα ζητάει από το χρήστη
     • το αρxικό ποσό και
     • τον αριθμό των περιόδων (ετών).
   • Στη συνέχεια ζητάει το επιτόκιο που ισχύει για κάθε περίοδο.
   • Στο τέλος εμφανίζει το τελικό ποσό της κατάθεσης.

Αποφάσεις και άλλες δομές ελέγχου

Η εντολή if-else

• Μπορούμε να εκτελέσουμε ορισμένες εντολές υπό συνθήκη με τη δομή ελέγχου If.
• Αυτή χρησιμοποιείται ως εξής:

  	If συνθήκη Then
  		εντολή
  		...
  	End If
  

• Οι εντολή που ακολουθεί το If εκτελείται αν η συνθήκη είναι αληθής.
• Παράδειγμα (υπολογίζει και τυπώνει την απόλυτη τιμή των αριθμών που διαβάζει μέχρι να συναντήσει το 0):

  Sub main()
      Dim Num As Integer
      
      Do
          Num = InputBox("Please enter a number")
          If Num < 0 Then
              Num = -Num
          End If
          MsgBox "The absolute value is " + Str(Num)
      Loop Until Num = 0
  End Sub
  

• Η δομή ελέγχου If μπορεί να ακολουθηθεί και από τη δομή Else για να προσδιορίσουμε εντολές που θα εκτελεστούν αν η συνθήκη δεν ισχύει. Παράδειγμα:

  	If grade >= 5 Then
  		MsgBox "Περνάει"
  	Else
  		MsgBox "Απορρίπτεται"
  	End If
  

• Μπορούμε να συνδυάσουμε συνεχόμενα Else If για πολλαπλούς ελέγχους. Παράδειγμα:

  	If grade >= 9 Then
  		MsgBox "'Αριστα!"
  	ElseIf grade >= 7 Then
  		MsgBox "Λίαν καλώς"
  	ElseIf grade >= 5 Then
  		MsgBox "Καλώς"
  	Else
  		MsgBox "Κακώς"
  	End If
  

H εντολή select

• Η εντολή select μας επιτρέπει να κατευθύνουμε τη ροή του προγράμματος προς μια συγκεκριμένη τιμή ανάλογα με την τιμή μιας παράστασης.
• Συντάσσεται ως εξής:

  	Select Case παράσταση
  	Case λίστα τιμών1
  		εντολή1
  		εντολή1α
  		...
  	Case λίστα τιμών2
  		εντολή2
  		...
  	...
  	Case Else
  		εντολή ν
  		...
  	End Select
  

• Ανάλογα με ποια από τις τιμές ισούται η τιμή της παράστασης εκτελούνται οι αντίστοιχες εντολές.
• Αν καμία από τις τιμές δεν ταυτίζεται με την τιμή της παράστασης τότε εκτελείται η εντολή που ακολουθεί την Case Else (αν υπάρχει), αλλιώς δεν εκτελείται καμία εντολή.
• Οι τιμές για κάθε case μπορεί να είναι
  • μια έκφραση (π.χ. 42 ή i + 9),
  • ο ορισμός μιας περιοχής με τη χρήση to (π.χ. 1 to 10)
  • μια σύγκριση της τιμής της απόφασης με μια έκφραση με τη χρήση της λέξης Is (π.χ. Is > 100)
  • ή ένα σύνολο από από τα παραπάνω χωρισμένα με , (π.χ. 3 to 5, 50, 90, is > LastVal)
• Παράδειγμα:

  Dim Number As Integer
  
  Number = InputBox("Enter a Number")
  Select Case Number	' Evaluate Number.
  Case 1 To 5	' Number between 1 and 5.
  	MsgBox "Between 1 and 5"
  Case 6, 7, 8	' Number between 6 and 8.
  	MsgBox "Between 6 and 8"
  Case Is > 8 And Number < 11	' Number is 9 or 10.
  	MsgBox "Greater than 8"
  Case Else	' Other values.
  	MsgBox "Not between 1 and 10"
  End Select
  

Η εντολή for

• Με την εντολή for μπορούμε εύκολα να εκτελέσουμε ένα βρόχο ορισμένες φορές.
• Συντάσσεται ως εξής:

  For μετρητής = αρχική τιμή To τελική τιμή [Step βήμα]
  	εντολή
  	...
  	[Exit For]
  	εντολή
  	...
  Next [μετρητής]
  

• O μετρητής είναι μια μεταβλητή που λαμβάνει όλες τις τιμές από την αρχική μέχρι την τελική τιμή ανά βήμα.
• Το τέλος του βρόχου δηλώνεται με την εντολή Next.
• Μπορούμε να τερματίσουμε το βρόχο πρόωρα με την εντολή Exit For
• Παραδειγμα:

  dim i as integer
  
  For i = 10 to 0 step -1
  	msgbox "Countdown: " + str(i)
  next i
  

Έξοδος από το βρόχο

• Με την εντολή Exit Do μπορούμε να τερματίσουμε ένα βρόχο Do πριν τον αρχικό ή τελικό έλεγχό του
• Η εντολή αυτή χρησιμοποιείται συχνά σε συνδυασμό με την If για να προσδιοριστεί η συνθήκη που θα προκαλέσει την έξοδο.
• Ορισμένες φορές ο βρόχος έχει προσδιοριστεί ως ατέρμων βρόχος (infinite loop) με μια πάντα-αληθή λογική έκφραση ελέγχου (π.χ. True).
• Παράδειγμα:

  do while true
  	i = InputBox("Give a number less than 100")
  	if i < 100 then
  		exit do
  	end if
  	msgbox "Try again"
  loop
  

Ασκήσεις

Αποφάσεις

1. Να γράψετε ένα πρόγραμμα που να υπολογίζει τη συνολική απόδοση μιας κατάθεσης με ετήσιο επιτόκιο που μεταβάλλεται κλιμακωτά ανάλογα με το ποσό που τοκίζεται σύμφωνα με τον παρακάτω πίνακα:

   Ποσό	Επιτόκιο
   0-999.999	2.25
   1.000.000-4.999.999	2.5
   5.000.000-10.000.000	2.8
   10.000.000 και άνω	2.9

   • Στην αρχή το πρόγραμμα ζητάει από το χρήστη
     • το αρxικό ποσό και
     • τον αριθμό των περιόδων (ετών).
   • Στο τέλος εμφανίζει το τελικό ποσό της κατάθεσης.

Προγραμματισμός με συμβολοσειρές

Ο τύπος της συμβολοσειράς

• Μπορούμε να ορίσουμε μεταβλητές με τύπο συμβολοσειρά με τον τύπο string:

  	Dim Name as String
  

• Οι μεταβλητές αυτές μπορούν να αποθηκεύσουν μεταβλητό αριθμό από χαρακτήρες.
• Οι σταθερές τύπου συμβολοσειράς γράφονται με τη χρήση των διπλών εισαγωγικών:

  	Dim Name as String
  
  	Name = "Γιώργος"
  

• Αν θέλουμε να παραστήσουμε εισαγωγικά σε μια σταθερή συμβολοσειρά τα γράφουμε με δύο διπλά εισαγωγικά:

  	Dim Msg as String
  
  	Msg = "Πατήστε ""Enter"" για να συνεχίσετε"
  

Συναρτήσεις για συμβολοσειρές

Len(string)

Επιστρέφει το μήκος μιας συμβολοσειράς

Left(string, length)

Επιστρέφει length χαραρακτήρες από αριστερά

Right(string, length)

Επιστρέφει length χαραρακτήρες από δεξιά

Mid(string, start[, length])

Επιστρέφει length χαρακτήρες από τη θέση start (ή όλη τη συμβολοσειρά από τη θέση start και μετά).

LTrim(string)

Αφαιρεί κενά στο αριστερό μέρος της συμβολοσειράς

RTrim(string)

Αφαιρεί κενά στο δεξί μέρος της συμβολοσειράς

Trim(string)

Αφαιρεί κενά αριστερά και δεξιά της συμβολοσειράς

Mid(stringvar, start[, length]) = string

Σύγκριση συμβολοσειρών

?

Ταιριάζει με οποιοδήποτε ένα χαρακτήρα

*

Ταιριάζει με μηδέν ή περισσότερους χαρακτήρες

#

Ταιριάζει με οποιοδήποτε ψηφίο

[λίστα]

Ταιριάζει με οποιοδήποτε χαρακτήρα στη λίστα (π.χ. [aeiyuio])

[!λίστα]

Ταιριάζει με οποιοδήποτε χαρακτήρα δεν περιέχεται στη λίστα

Παράδειγμα (ο βρόχος ελέγχει αν ο ταχυδρομικός κώδικας είναι γραμμένος σωστά):

Sub main()
    Dim PostCode As String
    Dim CodeOk As Boolean
    
    Do
        PostCode = InputBox("Δώστε ταχυδρομικό κώδικα")
        CodeOk = (PostCode Like "##[- ]###" Or PostCode Like "###[- ]##")
        If Not CodeOk Then
                MsgBox "Λάθος ταχυδρομικός κώδικας, δοκιμάστε ξανά."
        End If
    Loop Until CodeOk
End Sub

Πρόσβαση στο πρόχειρο

Dim Result as String

Result = Clipbboard.GetText

Clipboard.Clear
Clipboard.SetText("These are the new clipboard contents")

Ασκήσεις

Συμβολοσειρές

1. Να γράψετε ένα πρόγραμμα που να εμφανίζει στατιστικά στοιχεία για το περιεχόμενο του προχείρου. Το πρόγραμμα πρέπει να εμφανίζει τον αριθμό των χαρακτήρων, ψηφίων (0-9), λατινικών πεζών χαρακτήρων (a-z), λατινικών κεφαλαίων χαρακτήρων (A-Z) και ελληνικών αντίστοιχων χαρακτήρων που βρέθηκαν στο πρόχειρο.
2. Εκτελέστε το πρόγραμμά σας με είσοδο τον εαυτό του και με είσοδο ένα κείμενο από το Microsoft Word.

Προγραμματισμός με αριθμητικές τιμές

Αριθμητικοί τύποι

• Οι τύποι Integer και Long εκτελούνται με τη μέγιστη ταχύτητα.
• Οι τύποι Single και Double έχουν το μεγαλύτερο εύρος τιμών, αλλά δεν έχουν απόλυτη ακρίβεια. Δεν είναι καταλληλοι για λογιστικούς υπολογισμούς.

  Παράδειγμα:

  Sub main()
      Dim x As Double
      Dim i As Integer
      
      x = 0
      For i = 1 To 10000
          x = x + 0.1
      Next i
      MsgBox Str(x)	' Should be 1000
  End Sub
  

  
• Υπολογισμοί με Double και Short είναι τυπικά λιγότερο γρήγοροι από τους υπολογισμούς με Integer και Long.
• Ο τύπος Currency είναι ιδανικός για τη φύλαξη οικονομικών στοιχείων.
• Ο τύπος Decimal οδηγεί συχνά σε αργούς υπολογισμούς διότι δεν ταιριάζει με τον τρόπο που λειτουργεί ο υπολογιστής.

Μαθηματικές συναρτήσεις

Abs

Απόλυτη τιμή

Sgn

Πρόσημο

Fix

Αφαίρεση του δεκαδικού τμήματος (στρογγύλευση προς το 0)

Int

Στρογγύλευση προς τα κάτω

Sqr

Τετραγωνική ρίζα

Log

Φυσικός λογάριθμος

Exp

e υψωμένο σε δύναμη

Rnd

Ψευδοτυχαίος αριθμός 0 <= χ < 1. Αρνητικό όρισμα θέτει νέα αρχή για παραγωγή αριθμών, θετικό επιστρέφει τον επόμενο αριθμό της σειράς.

Sin

Ημίτονο

Cos

Συνημίτονο

Tan

Εφαπτομένη

Atn

Αντίστροφη εφαπτομένη

Λογιστικές συναρτήσεις

Μετατροπή αριθμών σε συμβολοσειρές

Format(έκφραση[, εμφάνιση])

0

Εμφανίζει ένα ψηφίο ή 0

#

Εμφανίζει ένα ψηφίο ή κενό

.

Καθορίζει το σημείο εμφάνισης των δεκαδικών τιμών

,

Καθορίζει το διαχωρισμό των χιλιάδων

%

Εμφανίζει το πηλίκο του αριθμού με το 100 ως ποσοστό

E+

Εμφανίζει τον αριθμό σε εκθετική μορφή με πρόσημο στους θετικούς εκθέτες

E-

Εμφανίζει τον αριθμό σε εκθετική μορφή χωρίς πρόσημο στους θετικούς εκθέτες

"σύμβολα"

Εμφανίζει τα σύμβολα μέσα στα εισαγωγικά

Sub main()
    Dim x As Currency
    
    x = 1500000
    MsgBox ("Κερδίσατε " + Format(x, "0,0.00 ""EUR""!"))
End Sub

Ορισμός συναρτήσεων και διαδικασιών

Ορισμός διαδικασίας

• Για να οργανώσουμε καλύτερα τον κώδικα που γράφουμε, αλλά και για να μπορούμε να χρησιμοποιούμε τα ίδια τμήματα του κώδικα πολλές φορές μπορούμε να ορίσουμε ένα σύνολο από εντολές ως μια διαδικασία (procedure) (στη Visual Basic υπορουτίνα (subroutine)).
• Μπορούμε να ορίσουμε δικές μας διαδικασίες με τον εξής τρόπο:

  Sub όνομα διαδικασίας()
  	δηλώσεις τοπικών μεταβλητών;
  
  	εντολές
  end Sub
  

• Στο πρόγραμμα η κλήση (call) της διαδικασίας γίνεται κάθε φορά που εμφανίζεται μια εντολή με το όνομα της διαδικασίας που ορίσαμε. Στο σημείο αυτό η εκτέλεση συνεχίζει με τις εντολές της διαδικασίας, και, όταν αυτές ολοκληρωθούν, η εκτέλεση επιστρέφει στο σημείο απ' όπου ξεκίνησε.
• Παράδειγμα:

  Sub main()
      hello
      MsgBox "Back from hello"
      hello
  End Sub
  
  ' Display hello world
  Sub hello()
      MsgBox "Hello, world"
  End Sub
  

• Κάθε διαδικασία έχει ένα όνομα. Στο πρόγραμμά μας χρησιμοποιούμε το όνομα της διαδικασίας όταν θέλουμε να εκτελεστεί ο αντίστοιχος κώδικας.
• Η εντολή exit sub μπορεί να εμφανιστεί σε οποιοδήποτε σημείο της διαδικασίας. Στο σημείο εκείνο σταματά η εκτέλεση της διαδικασίας και ο έλεγχος ροής (control flow) του προγράμματος συνεχίζει από το σημείο που κλήθηκε η συνάρτηση.
• Η διαδικασία Main είναι αυτή από την οποία ξεκινά η εκτέλεση του προγράμματος.

Ορίσματα

• Μπορούμε να μεταβάλουμε τη λειτουργικότητα μιας διαδικασίας με τη χρήση ορισμάτων. Κάθε όρισμα (argument) μεταφέρεται από το σημείο που καλούμε τη διαδικασία μέσα στη διαδικασία μέσω μιας ειδικής μεταβλητής.
• Τα ορίσματα της διαδικασίας είναι μια σειρά από ονόματα και τύπους μεταβλητών χωρισμένα με κόμμα.
• Όταν καλείται μια διαδικασία οι μεταβλητές που ορίστηκαν ως όρισμα παίρνουν τις τιμές που δόθηκαν κατά την κλήση.
• Παράδειγμα:

  Sub main()
      StrongMessage "Hello", 5, "*"
      StrongMessage "world", 10, "!"
  End Sub
  
  ' Display the message msg prefixed by n instances of the string s
  Sub StrongMessage(msg As String, n As Integer, s As String)
      Dim head As String
      
      ' Could use String(s, n) here
      For i = 1 To n
          head = head + s
      Next i
      MsgBox head + msg + head
  End Sub
  

         
  

Ορισμός συνάρτησης

• Μπορούμε ακόμα να ορίσουμε δικές μας συναρτήσεις με τον εξής τρόπο:

  Function όνομα συνάρτησης(δηλώσεις παραμέτρων) as τύπος αποτελέσματος
  	δηλώσεις τοπικών μεταβλητών;
  
  	εντολές
  	όνομα = τιμή
  end Function
  

• Οι παράμετροι της συνάρτησης είναι μια σειρά από τύπους και ονόματα μεταβλητών χωρισμένα με κόμμα.
• Όταν καλείται μια συνάρτηση οι μεταβλητές που ορίστηκαν ως παράμετροι παίρνουν τις τιμές που δόθηκαν στο όρισμα κατά την κλήση.
• Για να θέσουμε την τιμή που επιστρέφει η συνάρτηση αναθέτουμε μια τιμή στο όνομά της (δεν ορίζουμε αντίστοιχη μεταβλητή).
• Παράδειγμα:

  Sub main()
      MsgBox "64!=" + Str(factorial(45))
  End Sub
  
  ' Return n!
  Function factorial(n As Integer) As Double
      Dim i As Integer
      Dim r As Double ' result
      
      r = 1
      For i = 1 To n
          r = r * i
      Next i
      factorial = r
  End Function
  

  
• Η εντολή exit function μπορεί να εμφανιστεί σε οποιοδήποτε σημείο της συνάρτησης. Στο σημείο εκείνο σταματά η εκτέλεση της συνάρτησης και ο έλεγχος ροής του προγράμματος συνεχίζει από το σημείο που κλήθηκε η συνάρτηση.

Άσκηση

Διαδικασίες και συναρτήσεις

1. Να γράψετε μια συνάρτηση που να υπολογίζει τη συνολική απόδοση μιας κατάθεσης με ετήσιο επιτόκιο που μεταβάλλεται κλιμακωτά ανάλογα με το ποσό που τοκίζεται σύμφωνα με τον παρακάτω πίνακα:

   Ποσό	Επιτόκιο
   0-999.999	2.25
   1.000.000-4.999.999	2.5
   5.000.000-10.000.000	2.8
   10.000.000 και άνω	2.9

   • Με βάση την παραπάνω συνάρτηση να γράψετε ένα πρόγραμμα που ζητάει διαδοχικά (συνεχώς) από το χρήστη
     • το αρxικό ποσό και
     • τον αριθμό των περιόδων (ετών).
     και εμφανίζει το τελικό ποσό της κάθε κατάθεσης.
   • Το πρόγραμμα τερματίζει τη λειτουργία του όταν ο χρήστης εισάγει 0 στο αρχικό ποσό.

Βασικές αρχές αντικειμενοστρεφούς προγραμματισμού

Στοιχεία αντικεμενοστρεφούς προγραμματισμού

• Κάθε οντότητα είναι ένα αντικείμενο (object).
• Υπολογισμοί γίνονται όταν ένα αντικείμενο στείλει ένα μήνυμα (message) σε άλλο αντικείμενο (ή - σύμφωνα με την επικρατέστερη ορολογία - καλέσει μια μέθοδο (method) ενός άλλου αντικειμένου.) Μια μέθοδος μπορεί να έχει ως όρισμα στοιχεία που είναι απαραίτητα για την εκτέλεση του υπολογισμού.
• Κάθε αντικείμενο έχει τη δική του μνήμη για να αποθηκεύει την κατάστασή του. Οι μεταβλητές στις οποίες αποθηκεύεται η κατάσταση αυτή καλούνται ιδιότητες (properties) (ή μεταβλητές στιγμιότυπου (instance variables)).
• Κάθε αντικείμενο αποτελεί στιγμιότυπο (instance) μιας κλάσης. Η κλάση (class) είναι μια ομάδα από ομοειδή αντικείμενα.
• Η κλάση είναι ο χώρος στον οποίο ορίζεται η συμπεριφορά των αντικειμένων. Όλα τα αντικείμενα μιας κλάσεις μοιράζονται την ίδια συμπεριφορά (εκτελούν τις ίδιες μεθόδους).
• Οι κλάσεις μπορούν να οργανωθούν σε μια δενδρική δομή που ορίζει κληρονομικότητα (inheritance). Ιδιότητες και μέθοδοι που έχουν οριστεί σε μια μητρική κλάση κληρονομούνται και είναι προσβάσιμες και από κάθε υποκλάση (subclass) της.

Υλοποίηση κλάσεων

• Η Visual Basic επιτρέπει τον προγραμματισμό με αντικείμενα και χρησιμοποιεί αντικείμενα ως βάση για την υλοποίηση γραφικών διεπαφών.
• Μερικά στοιχεία του αντικειμενοστρεφούς προγραμματισμού, όπως η κληρονομικότητα, δεν υποστηρίζονται άμεσα από τη γλώσσα, αλλά υλοποιούνται μέσω συμβάσεων και εργαλείων που τις υλοποιούν.
• Ο ορισμός των κλάσεων (αλλά όχι και οι μετέπειτα αλλαγές) υποστηρίζεται από το εργαλείο Class Builder.

Το εργαλείο Class Builder

Ορισμός ιδιότητας

Οι ιδιότητες είναι μεταβλητές που αποτελούν τμήμα του κάθε αντικειμένου.

Ορισμός μεθόδου

Κάθε μέθοδος είναι μια διαδικασία ή συνάρτηση που έχει πρόσβαση στις ιδιότητες του συγκεκριμένου αντικειμένου.

Ορισμός κληρονομικότητας

Οι ιδιότητες και μέθοδοι του αντικειμένουν Point κληρονομούνται από το αντικείμενο Point3D.

Προγραμματισμός με αντικείμενα

• Αφού ορίσουμε τα στοιχεία μιας κλάσης πρέπει να γράψουμε τον κώδικα για τις αντίστοιχες μεθόδους. Παράδειγμα:

  Public Function Distance() As Double
      Distance = Sqr(x * x + y * y)
  End Function
  

• Για να χρησιμοποιήσουμε αντικείμενα που έχουμε ορίσει πρέπει να τα δηλώσουμε με την εντολή Dim και στη συνέχεια να τους εκχωρήσουμε χώρο με τη χρήση της εντολής Set ... New.
• Σε κάθε αντικείμενο έχουμε πρόσβαση στις μεθόδους και τις ιδιότητές του με τη σύνταξη όνομα.ιδιότητα ή όνομα.μέθοδος όρισμα. Παράδειγμα:

  Sub main()
      Dim a As Point
      
      Set a = New Point
      a.x = 4
      a.y = 3
      MsgBox a.Distance
      a.MoveTo 3, 4
      MsgBox a.Distance
  end sub
  

• Συχνά χρησιμοποιούμε έτοιμα αντικείμενα που υποστηρίζει το περιβάλλον της Visual Basic:

  Sub main()
      App.Title = "Hello, world"
      Clipboard.Clear
      Clipboard.SetText ("New clipboard contents")
      MsgBox App.Path
  End Sub
  

Αντικειμενοστρεφής σχεδιασμός με UML

Εισαγωγή

Σχεδιάζουμε για να μπορέσουμε να καταλάβουμε το σύστημα που αναπτύσσουμε. Έτσι δημιουργώντας ένα σχέδια επιτυγχάνουμε τέσσερις στόχους:

1. παριστάνουμε οπτικά το σύστημα που έχουμε ή θέλουμε να κατασκευάσουμε,
2. προσδιορίζουμε τη δομή και τη συμπεριφορά του συστήματος,
3. δημιουργούμε ένα πρότυπο για να βασίσουμε την κατασκευή του συστήματος,
4. τεκμηριώνουμε τις αποφάσεις που λάβαμε.

Σε όλους τους τεχνολογικούς τομείς ο σχεδιασμός βασίζεται σε τέσερις βασικές αρχές:

1. η επιλογή του είδους του σχεδίου έχει επίπτωση στον τρόπο και την μορφή επίλυσης του προβλήματος,
2. όλα τα σχέδια εκφράζονται σε διαφορετικές βαθμίδες ακρίβειας,
3. τα καλύτερα σχέδια σχετίζονται με την πραγματικότητα,
4. ένα είδος σχεδίων δεν είναι ποτέ αρκετό.

Η UML περιλαμβάνει τρία βασικά στοιχεία:

1. Οντότητες
2. Σχέσεις
3. Διαγράμματα

Κλάσεις

• Μια κλάση σχεδιάζεται ως ένα ορθογώνιο με τρία τμήματα όπως στο παρακάτω σχήμα:
  
• Τα ονόματα των ιδιοτήτων και μεθόδων της κλάσης μπορούν να έχουν ένα πρόθεμα ανάλογα με την ορατότητά τους:

  +

  public

  #

  protected

  -

  private

• Οι μεταβλητές και οι συναρτήσεις που αναφέρονται στην κλάση και όχι σε αντικείμενά της (static στη C++) σχεδιάζονται υπογραμμισμένες.
• Οι αφηρημένες κλάσεις έχουν το όνομά τους γραμμένο με πλάγια στοιχεία.
• Το σχήμα που ακολουθεί αποτελεί σχέδιο για μια απλή κλάση στοίβας ακεραίων:
  

Σχέσεις

1. εξάρτηση (dependency)
2. γενίκευση (generalisation)
3. σύνδεση (association)

Εξάρτηση

Γενίκευση

Σύνδεση

• Αν η σύνδεση δεν είναι αμφίδρομη τότε η κατεύθυνσή της μπορεί να οριστεί με ένα ανοιχτό βέλος.
• Το όνομα της σύνδεσης μπορεί να γραφεί πάνω από τη γραμμή, ενώ η κατεύθυνση του ονόματος ορίζεται από ένα βέλος πλάι στο όνομα.
• Ο ρόλος των οντοτήτων που συνδέονται προσδιορίζεται από ένα όνομα στην κάθε άκρη της γραμμής.
• Ο αριθμός που δηλώνει πόσα αντικείμενα αντιστοιχούν σε κάθε αντικείμενο στην άλλη άκρη της σχέσης (πολλαπλότητα (multiplicity)) δηλώνεται από έναν αριθμό (π.χ. 3), ή μια περιοχή αριθμών (π.χ. 1..* για ένα έως πολλά) πάνω από την αντίστοιχη άκρη της γραμμής.

Αν σε μια σχέση τα αντικείμενα απαρτίζουν τμήματα ενός όλου, τότε αυτή απεικονίζεται ως συγκρότημα (aggregation) με την παράσταση ενός διαμαντιού στην άκρη του "όλου".

Αν σχέση τα αντικείμενα που απαρτίζουν τμήματα ενός όλου έχουν την ίδια διάρκεια ζωής με το όλο, τότε αυτή απεικονίζεται ως σύνθεση (composition) με την παράσταση ενός γεμάτου διαμαντιού στην άκρη του "όλου".

Είδη εξαρτήσεων

πρόσβαση (access)

Άδεια σε κάποια στοιχεία από ένα τμήμα να έχουν πρόσβαση σε στοιχεία από άλλο τμήμα (access).

σύνδεση (binding)

Παροχή τιμών σε ένα πρότυπο για να δημιουργήσει ένα νέο στοιχείο (bind).

κλήση (call)

Μια μέθοδος καλεί μια άλλη (call).

απόρρεια (derivation)

Ένα στοιχείο που μπορεί να υπολογιστεί από κάποιο άλλο (derive).

friend

Ένα στοιχείο μπορεί να έχει πρόσβαση σε στοιχεία άλλης κλάσης παρά τους όποιους περιορισμούς (friend).

εισαγωγή (import)

Άδεια σε ένα τμήμα να εισάγει και να χρησιμοποιήσει τα στοιχεία ενός άλλου τμήματος (import).

δημιουργία (instantiation)

Μια μέθοδος μιας κλάσης δημιουργεί αντικείμενα μιας άλλης κλάσης (instantiate).

παράμετρος (parameter)

Σχέση ανάμεσα σε μια λειτουργία και τις παραμέτρους της (parameter).

δημιουργία (realization)

Σχέση ανάμεσα σε μια προδιαγραφή και την υλοποίησή της (realize).

εκλέπτυνση (refinement)

Δήλωση για την ύπαρξη απεικόνισης ανάμεσα σε δύο σημασιολογικά επίπεδα (refine).

αποστολή (send)

Σχέση ανάμεσα στον αποστολέα και τον παραλήπτη ενός μηνύματος (send).

ίχνος (trace)

Σχέση ανάμεσα σε δύο στοιχεία δύο διαφορετικών μοντέλων που δεν αποτελεί όμως απεικόνιση (trace).

χρήση (usage)

Ένα στοιχείο απαιτεί την ύπαρξη ενός άλλου στοιχείο για τη λειτουργία του (π.χ. call, instantiate, parameter, send) (use).

Διάγραμμα κλάσεων

Διάγραμμα αντικειμένων

Το σύνολο των αντικειμένων σχεδιάζεται με βάση τους συνδέσμους που ορίζονται πάνω σε αυτό.

Βιβλιογραφία

• Grady Booch, James Rumbaugh, and Ivar Jacobson. The Unified Modeling Language User Guide. Addison-Wesley, 1999.

• James Rumbaugh, Ivar Jacobson, and Grady Booch. The Unified Modeling Language Reference Manual. Addison-Wesley, 1999.

• Roel Wieringa. A survey of structured and object-oriented software specification methods and techniques. ACM Computing Surveys, 30(4):459–527, December 1998.

Διεπαφή χρήστη

Παράθυρα, εικονίδια, μενού, και δείκτης

Το περιβάλλον αυτό σχεδιάστηκε για πρώτη φορά στο Palo Alto Research Center της Xerox (PARC) και υλοποιήθηκε με επιτυχία από την Apple για τους υπολογιστές Macintosh και από τη Micosoft στην οικογένεια Windows. Η επιφάνεια εργασίας χρησιμοποιεί ως βάση τη μεταφορά του γραφείου (desktop metaphor). Ο χρήστης μετακινεί πάνω στην οθόνη παράθυρα με τη χρήση του δείκτη όπως θα κινούσε έγγραφα στο γραφείο με τα χέρια του. Βασικά τεχνολογικά στοιχεία για τη λειτουργία του περιβάλλοντος αυτού είναι η οθόνη χαρτογραφικής απεικόνισης (bitmap display) και το ποντίκι (mouse) ή κάποιος άλλος αντίστοιχος μηχανισμός που επιτρέπει στο χρήστη να δείχνει αντικείμενα στην οθόνη. Με τη χρήση εικονιδίων ορισμένα στοιχεία του περιβάλλοντος μπορούν να παρασταθούν με αμεσότητα, ενώ τα μενού κάνουν τις λειτουργίες του περιβάλλοντος προσιτές χωρίς να χρειάζεται ο χρήστης να απομνημονεύει εντολές και τη σύνταξή τους.

Εικονίδια στο περιβάλλον Windows

Εισαγωγή εικόνας στο κείμενο με τη χρήση μενού στο πρόγραμμα Microsoft Word

<img src="./ui/inspic.gif"> 

Εσωτερική δομή

Για την επιβολή συνέπειας στη διεπαφή με το χρήστη αλλά και τη διευκόλυνση υλοποίησης των εφαρμογών τα παραθυρικά περιβάλλοντα ορίζουν μια σειρά από όργανα (controls) (ή widgets) τα οποία ενσωματώνουν και διαθέτουν ένα σύνολο από λειτουργίες που είναι συχνά χρήσιμες. Παραδείγματα τέτοιων οργάνων είναι το πλαίσιο εισαγωγής κειμένου (edit box), το πιεζόμενο κουμπί (push button) και το πλαίσιο επιλογής αρχείου.

Η μεταφορά των γεγονότων από το σύστημα στις εφαρμογές και τα παράθυρά τους βασίζεται συχνά στην κληρονομικότητα. Έτσι, μια εφαρμογή μπορεί να δημιουργήσει υποκλάσεις για ένα όργανο που να δίνουν στο όργανο πιο εξειδικευμένη λειτουργικότητα. Αντίστοιχα, τα μηνύματα από το σύστημα κατεβαίνουν το δέντρο της κληρονομικότητας μιας εφαρμογής μέχρι και το τελευταίο στην ιεραρχία παράθυρο ή όργανο να δει το γεγονός και να έχει την ευκαιρία να το χειριστεί. Μια εφαρμογή πρέπει να παραλαμβάνει συνέχεια όλα τα μηνύματα που στέλνονται σε αυτή, να τα διαχωρίζει και να τα προωθεί στους αντίστοιχους παραλήπτες.

Απεικόνιση της δομής στη Visual Basic

• ιδιότητες όπως για παράδειγμα τη θέση και το χρώμα του,
• μεθόδους που μπορούν να κληθούν για εκτέλεση όπως για παράδειγμα τη μέθοδο της επανασχεδίασης και
• γεγονότα στα οποία μπορεί ο χρήστης να συνδέσει κώδικα π.χ. το γεγονός click.

• Κατά τη διάρκεια σχεδιασμού της εφαρμογής, ο χρήστης μπορεί να διαβάσει και να αλλάξει τιμή στις περισσότερες ιδιότητες καθώς και να συνδέσει κώδικα με όλα τα γεγονότα κάθε οργάνου.
• Κατά τη διάρκεια εκτέλεσης της εφαρμογής, το πρόγραμμα μπορεί να διαβάσει και να αλλάξει τιμή στις περισσότερες ιδιότητες και να καλέσει τις μεθόδους του κάθε οργάνου. Όταν παραλαμβάνεται από την εφαρμογή ένα γεγονός, αυτό προωθείται αυτόματα στον κώδικα που έχει συνδεθεί με το αντίστοιχο όργανο. Αν δεν υπάρχει τέτοιος κώδικας, τότε η εφαρμογή εκτελεί αυτόματα κώδικα ο οποίος εκτελεί τη βασική λειτουργία για το αντίστοιχο γεγονός.

Όργανα

Το περιβάλλον της Visual Basic ορίζει τα παρακάτω βασικά όργανα:

TextBox

Όργανο για είσοδο κειμένου

Label

Εμφάνιση κειμένου

PictureBox

Περιοχή για εμφάνιση και σχεδίαση γραφικών κατά τη διάρκεια εκτέλεσης του προγράμματος.

CheckBox

Επιλογή τύπου ναι/όχι (μπορούν να είναι αληθείς πολλαπλές τέτοιες επιλογές)

OptionButton

Επιλογή τύπου ναι/όχι (δεν μπορούν να είναι αληθείς πολλαπλές τέτοιες επιλογές)

CommandButton

Κουμπί για εντολές

Image

Χαρτογραφική εικόνα που μπορεί να ορίσει ο χρήστης

Shape

Σχήμα που μπορεί να οριστεί κατά τη σχεδίαση της εφαρμογής.

Timer

Χρονόμετρο που δημιουργεί γεγονότα σε τακτά διαστήματα.

ListBox

Λίστα με επιλογές.

ComboBox

Λίστα με επιλογές σε συνδυασμό με περιοχή που μπορεί να γραφτεί κείμενο

VScrollBar

Κάθετο όργανο ελέγχου της θέσης στο παράθυρο.

HScrollBar

Οριζόντιο όργανο ελέγχου της θέσης στο παράθυρο.

Frame

Περιοχή στην οποία μπορούν να ομαδοποιηθούν πολλά όργανα (ειδικά OptionButton)

Γεγονότα

Click

Click του ποντικιού πάνω στο όργανο.

DblClick

Διπλό click του ποντικιού πάνω στο όργανο.

GotFocus

Το όργανο γίνεται η εστία εισόδου.

LostFocus

Το όργανο παύει να είναι η εστία εισόδου.

KeyDown

Ένα πλήκτρο πατιέται πάνω από το όργανο.

KeyUp

Ένα πλήκτρο αφήνεται πάνω από το όργανο.

KeyPress

Ένας χαρακτήρας γράφεται πάνω από το όργανο.

MouseDown

Ένα πλήκτρο του ποντικιού πατιέται πάνω από το όργανο.

MouseUp

Ένα πλήκτρο του ποντικιού αφήνεται πάνω από το όργανο.

MouseMove

Το ποντίκι κινείται πάνω από το όργανο.

Change

Τα δεδομένα που περιέχει το όργανο άλλαξαν.

Private Sub Check1_KeyPress(KeyAscii As Integer)

End Sub

Private Sub Check1_KeyUp(KeyCode As Integer, Shift As Integer)

End Sub

Private Sub Check1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)

End Sub

Private Sub Command1_Click()

End Sub

Private Sub Text1_Change()

End Sub

Ιδιότητες

Name

Το όνομα του συγκεκριμένου οργάνου.

BackColor

Το χρώμα του φόντου.

ForeColor

Το χρώμα σχεδίασης.

Enabled

Αληθές αν το όργανο είναι ενεργό.

Visible

Αληθές αν το όργανο είναι ορατό.

Text

Το κείμενο που περιέχει το όργανο.

Caption

Το κείμενο που εμφανίζει το όργανο.

Value

Η τιμή που έχει το όργανο (π.χ. αληθές/ψευδές).

ToolTipText

Το αναδυόμενο κείμενο σύντομης βοήθειας.

Height

Το ύψος του οργάνου.

Left

Η θέση του οργάνου στη φόρμα από αριστερά.

Top

Η θέση του οργάνου στη φόρμα από πάνω.

Width

Το πλάτος του οργάνου.

Υλοποίηση προγραμμάτων

• Τα προγράμματα που υλοποιούν γραφική επαφή σε Visual Basic αποτελούνται από μια ή περισσότερες φόρμες και τα όργανα που υπάρχουν πάνω σε αυτές.
• Για κάθε όργανο που τοποθετούμε στη φόρμα (αλλά και για την ίδια τη φόρμα) ορίζουμε τις αρχικές ιδιότητές του από στην αντίστοιχη περιοχή του περιβάλλοντος εργασίας:
  
• Στα προγράμματα που ορίζοτν διεπαφή με φόρμες σπάνια ορίζουμε η εκτέλεση να αρχίζει από τη διαδικασία Main.
• Η λειτουργία του προγράμματος βασίζεται σε κώδικα που ανταποκρίνεται σε συγκεκριμένα γεγονότα (π.χ. το click σε ένα κουμπί).
• Για παράδειγμα με ο παρακάτω κώδικας υλοποιεί (λανθασμένα ως προς τη στρογγυλοποίηση) το πρόγραμμα μετατροπής μεταξύ Ευρώ και δραχμών.

  Private Sub cmdExit_Click()
      End
  End Sub
  
  Private Sub cmdToGRD_Click()
      txtGRD.Text = Format(Val(txtEUR.Text) * 340.57, "#")
  End Sub
  
  Private Sub cmdToEUR_Click()
      txtEUR.Text = Format(Val(txtGRD.Text) / 340.75, ".##")
  End Sub
  

  

Βιβλιογραφία

• Microsoft Developer Network Library Visual Studio Documentation - Visual Basic - Reference - Controls Reference - Intrinsic Controls
• Michael Halvorson Visual Basic 6 Βήμα προς βήμα. Εκδόσεις Κλειδάριθμος, Αθήνα.

• Stuart K. Card, Thomas P. Moran, and Allen Newell. The Psychology of Human-Computer Interaction. Lawrence Erlbaum Associates, Publishers, New Jersey, USA, 1983.

• Adele Goldberg. Smalltalk 80: The Language and its Implementation. Addison Wesley, 1980.

• Brian W. Kernighan. Experience with Tcl slash Tk for scientific and engineering visualization. In Proceedings of the Tcl slash Tk Workshop, pages 269–278, Toronto, Ontario, Canada, July 1995.

• Microsoft Corp. Windows Interface Guidelines for Software Design. Microsoft Press, Redmond, WA, USA, 1995.

• Donald A. Norman. The Psychology of Everyday Things. BasicBooks, New York, NY, USA, 1988.

• Donald A. Norman. The Invisible Computer. MIT Press, 1998.

• John K. Ousterhout. Tcl and the Tk Toolkit. Addison-Wesley, 1994.

• Diomidis Spinellis. A critique of the Windows application programming interface (http://kerkis.math.aegean.gr/~dspin/pubs/jrnl/1997-CSI-WinApi/html/win.html). Computer Standards & Interfaces, 20:1–8, November 1998.

• J. J. Thomas and G. Hamlin. Graphical input interaction technique workshop summary. Computer Graphics, pages 5–30, January 1983.

• Edward R. Tufte. The Visual Display of Quantitative Information. Graphics Press, 1983.

Ασκήσεις

Διεπαφές

1. Να υλοποιήσετε μια φιλική γραφική διεπαφή για ένα από τα προγράμματα που έχετε γράψει στα πλαίσια του μαθήματος.

Διαχείριση δεδομένων: σύνδεση με βάσεις δεδομένων, πίνακες, τύποι

Πρόσβαση σε βάσεις δεδομένων

• τη βέλτιστη τεχνολογία πρόσβασης στα δεδομένα (η Microsoft αναβαθμίζει συχνά τις τεχνολογίες αυτές με ονόματα όπως ODBC, DAO, RDO, ADO, .net),
• τον τρόπο με τον οποίο είναι υλοποιημένη η επιχειρηματική λογική,
• τις άδειες πρόσβασης των χρηστών,
• προβλήματα πολλαπλής χρήσης της βάσης,
• τον τρόπο κίνησης και εμφάνισης σε μεγάλο όγκο δεδομένων.

Πρόσβαση από τη διεπαφή του χρήστη

• H Visual Basic επιτρέπει την εύκολη πρόσβαση σε βάσεις και άλλες πηγές δεδομένων με τη χρήση του Data Control.
• Το data control συνδέει πεδία της φόρμας στην οποία το τοποθετούμε με τη βάση δεδομένων.
  
• Στο data control καθορίζουμε τη σύνδεση με τις παρακάτω παραμέτρους:

  Connect

  Τύπος της σύνδεσης, π.χ. Access για βάσεις δεδομένων Excel για φύλα εργασίας ή το όνομα πηγής δεδομένων ODBC.

  DefaultType

  UseODBC ή UseJet.

  DatabaseName

  To αρχείο της βάσης δεδομένων.

  Exclusive

  Αν η πρόσβαση στη βάση θα είναι αποκλειστική.

  ReadOnly

  Αν η πρόσβαση στη βάση θα είναι μόνο για ανάγνωση.

  RecordSource

  Ο πίνακας ή η θέα της βάσης που θέλουμε να έχουμε πρόσβαση.

• Κατά τη λειτουργία του προγράμματος το data control επιτρέπει στο χρήστη την κίνηση από εγγραφή σε εγγραφή.
• Στη φόρμα τοποθετούμε πεδία συνδεδεμένα με τη βάση δεδομένων (data bound controls) και τα συνδέουμε με το data control.

Εμφάνιση και αλλαγή στοιχείων

• Πολλά από τα όργανα της Visual Basic επιτρέπουν την άμεση σύνδεσή τους με μια πηγή δεδομένων μέσω του data control.
• Ορισμένα από τα όργανα αυτά είναι τα παρακάτω:
  • CheckBox
  • ComboBox
  • Image
  • Label
  • ListBox
  • MaskedEdit
  • PictureBox
  • ProgressBar
  • RichTextBox
  • TextBox
• Η σύνδεση γίνεται με δύο ιδιότητες.

  DataSource:

  ορίζει το data control με το οποίο θα γίνεται η πρόσβαση στην πηγή των δεδομένων.

  DataField:

  ορίζει το πεδίο του πίνακα ή της θέας που θα αντιστοιχεί στο συγκεκριμένο όργανο.

• Όταν ένα όργανο συνδεθεί με μια πηγή δεδομένων, κινήσεις ανάμεσα σε εγγραφές που γίνονται από το data control, ενημερώνουν αυτόματα τα περιεχόμενά του με τα αντίστοιχα περιεχόμενα των εγγραφών της βάσης.
• Αντίστροφα, αλλαγές που κάνει ο χρήστης στα περιεχόμενα του οργάνου μεταφέρονται στη βάση όταν ο χρήστης μετακινηθεί σε άλλη εγγραφή.

Πρόσβαση στη βάση από το πρόγραμμα

• Πολλές φορές η απλοϊκή πρόσβαση στη βάση μέσω του data control δεν είναι αρκετή και απαιτείται ανάγνωση και εγγραφή των δεδομένων μέσα από το πρόγραμμα.
• Το πρώτο βήμα είναι η σύνδεση με τη βάση δεδομένων:

      Dim dbsDb As Database
      Set dbsDb = OpenDatabase("Inventory.mdb")
  

• Επειδή η σύνδεση αυτή απαιτεί συχνά χρόνο για να δημιουργηθεί συχνά την κρατάμε για όλο το διάστημα λειτουργίας του προγράμματος σε μια καθολική μεταβλητή (global variable):

      Global dbsDb As Database
  
      Sub Main()
      Set dbsDb = OpenDatabase("Inventory.mdb")
  

• Πρόσβαση στα δεδομένα έχουμε μέσω του συνόλου εγγραφών RecordSet.
• Για να μη βασιζόμαστε στη δομή των πινάκων της βασης προτείνουμε κάθε πρόσβαση να γίνεται μέσω μιας ερώτησης (query) ή αποθηκευμένης διαδικασίας (stored procedure) της βάσης με τις αντίστοιχες παραμέτρους.
• Πρόσβαση στις ερωτήσεις έχουμε μέσω του αντικειμένου QueryDef.

      Dim qry As QueryDef
      Dim rst As Recordset
      
      Set qry = dbsDb.QueryDefs("ComputerById")
      qry.Parameters("Id") = "34673"
  

• Με βάση την ερώτηση μπορούμε να ανακτήσουμε τις εγγραφές:

      Set rst = qry.OpenRecordset
  

• Στη συνέχεια μπορούμε να περάσουμε από κάθε εγγραφή με ένα βρόχο:

      do while not rst.EOF 
      	...
      loop
  

• ή να ελέγξουμε να υπάρχουν αποτελέσματα που να ικανοποιούν τη συνθήκη αυτή:

      If not rst.EOF Then
      	...
  

• Πρόσβαση στα πεδία των εγγραφών έχουμε με βάση το όνομα του κάθε πεδίου:

      MsgBox rst("ItemName")
  

• Όταν θέλουμε να μεταβάλλουμε τα περιεχόμενα των πεδίων πρέπει πρώτα να καλέσουμε τη μέθοδο Edit, ενώ για να προσθέσουμε μια νέα εγγραφή καλούμε τη μέθοδο AddNew:

      if rst.EOF
          rst.AddNew
      Else
          rst.Edit
      End If
      rst("ItemName") = "The Art of Computer Programming"
  

• Όταν ολοκληρωθούν οι αλλαγές καλούμε τη μέθοδο Update:

      rst.Update
  

• Στο τέλος της πρόσβασης στα δεδομένα καλούμε τη μέθοδο Close για κάθε Open που χρησιμοποιήσαμε:

      rst.Close
      qry.Close
      dbsDB.Close
  

Πίνακες

• Ορισμένες φορές χρειάζεται να ομαδοποιήσουμε δεδομένα ίδιου τύπου.
• Αν τα δεδομένα αυτά δεν απαιτούνται όταν το πρόγραμμα τερματίσει τη λειτουργία του, αντί να τα φυλάξουμε σε βάση δεδομένων, μπορούμε να χρησιμοποιήσουμε έναν πίνακα (array).
• Ο ορισμός του πίνακα γίνεται με τη σύνταξη:

  	Dim όνομα([κάτω-όριο Το] άνω-όριο [, [κάτω-όριο Το] άνω-όριο] ...) as τύπος
  

• Αν δεν οριστεί το κάτω όριο είναι το 0 (ή αυτό που έχουμε ορίσει με την εντολή option base).
• Αν δώσουμε πολλαπλές τιμές ορίζουμε πίνακα πολλαπλών διαστάσεων.
• Παράδειγμα:

  	Dim Values(10) as Integer
  	Dim RoomEmpty(100 to 999) as Boolean
  	Dim ChessBoard(7, 7) as String
  

• Πρόσβαση στα δεδομένα του πίνακα έχουμε με το όνομα της μεταβλητής και τον ακέραιο δείκτη στο στοιχείο που μας ενδιφέρει μέσα σε παρένθεση:

  	Values(3) = 178
  	For i= 100 to 999
  		RoomEmpty(i) = True
  	Next i
  	ChessBoard(0, 1) = "Castle"
  

Τύποι καθοριζόμενοι από το χρήστη

• Ορισμένες φορές χρειάζεται να ομαδοποιήσουμε δεδομένα διαφορετικών τύπων μεταξύ τους. Για το σκοπό αυτό μπορούμε να ορίσουμε έναν νέο τύπο (type) δεδομένων ως μια δομή (structure).
• Τη δυνατότητα αυτή μας δίνει η εντολή Type με την παρακάτω σύνταξη:

  Type όνομα
  	πεδίο1 As τύπος
  	πεδίο2 As τύπος
  	...
  End Type
  

• Παράδειγμα:

  Type CustomerEntry
  	Name As String
  	Phone As String
  	Balance As Currency
  End Type
  

• Τα στοιχεία μπορούν να είναι και πίνακες σύμφωνα με τη σύνταξη που ορίζουμε τις αντίστοιχες μεταβλητές.
• Με βάση τον τύπο που ορίσαμε μπορούμε να ορίσουμε νέες μεταβλητές:

  	Dim CurrentCustomer As CustomerEntry
  	Dim AllCustomers(100) As CustomerEntry 
  

• Πρόσβαση στα πεδία της δομής έχουμε με τη σύνταξη μεταβλητή.πεδίο:

  	Dim TotalBalance as Currency
  
  	MsgBox CurrentCustomer.Name + CurrentCustomer.Phone
  	For i = 1 to 100
  		TotalBalance = TotalBalance + AllCustomers(i).Balance
  	Next i
  

Βιβλιογραφία

• Timothy Andrew and Craig Harris. Combining language and database advances in an object-oriented development environment. ACM SIGPLAN Notices, 22(12):430–440, December 1987. Special Issue: Object-Oriented Programming Systems, Languages and Applications, OOPSLA '87 Conference Proceedings, October 4–8 Orlando, Florida, USA.

• Peter Duchessi and InduShobha Chengalur-Smith. Client/server benefits, problems, best practices. Communications of the ACM, 41(5):87–94, May 1998.

• John G. Hughes. Object-Oriented Databases. Prentice Hall, 1991.

• Joel Kanter. Understanding Thin-Client/Server Computing. Microsoft Press, Redmond, WA, USA, 1998.

• Henry F. Korth and Abraham Silberschatz. Database System Concepts. McGraw-Hill, second edition, 1991.

• Scott M. Lewandowski. Frameworks for component-based client/server computing. ACM Computing Surveys, 30(1):3–27, March 1998.

• Alok Sinha. Client-server computing. Communications of the ACM, 35(7):77–98, July 1992.

• Diomidis Spinellis. The computer's new clothes (http://softlab.icsd.aegean.gr/~dspin/pubs/jrnl/1998-IEEESoft-CliServ/html/CliServ.html). IEEE Software, 15(6):14–17, November/December 1998.

• D. C. Tsichritzis and O. M. Nierstrasz. Directions in object-oriented research. In Won Kim and Frederick H. Lochovsky, editors, Object-Oriented Concepts, Databases, and Applications, chapter 20, pages 523–536. Addison-Wesley, 1989. ACM Press Frontier Series.

Ασκήσεις

  URI            = ( absoluteURI | relativeURI ) [ "#" fragment ]

  absoluteURI    = scheme ":" *( uchar | reserved )

  relativeURI    = net_path | abs_path | rel_path

  net_path       = "//" net_loc [ abs_path ]
  abs_path       = "/" rel_path
  rel_path       = [ path ] [ ";" params ] [ "?" query ]

  path           = fsegment *( "/" segment )
  fsegment       = 1*pchar
  segment        = *pchar

  params         = param *( ";" param )
  param          = *( pchar | "/" )
  scheme         = 1*( ALPHA | DIGIT | "+" | "-" | "." )
  net_loc        = *( pchar | ";" | "?" )

  query          = *( uchar | reserved )
  fragment       = *( uchar | reserved )

  pchar          = uchar | ":" | "@" | "&" | "=" | "+"
  uchar          = unreserved | escape
  unreserved     = ALPHA | DIGIT | safe | extra | national

  escape         = "%" HEX HEX
  reserved       = ";" | "/" | "?" | ":" | "@" | "&" | "=" | "+"
  extra          = "!" | "*" | "'" | "(" | ")" | ","
  safe           = "$" | "-" | "_" | "."
  unsafe         = CTL | SP | <"> | "#" | "%" | "<" | ">"
  national       = <any OCTET excluding ALPHA, DIGIT,
		   reserved, extra, safe, and unsafe>

http://kerkis.math.aegean.gr/~dspin/
http://www.altavista.com/cgi-bin/query?pg=q&text=yes&q=link%3akerkis%2emath%2eaegean%2egr%2f%7edspin+%2dhost%3akerkis%2emath%2eaegean%2egr&stq=10&c9k

GET /pub/WWW/TheProject.html HTTP/1.1
Host: www.w3.org

<όνομα ετικέτας παράμετροι>

<ετικέτα>
περιοχή που σημειώνεται
</ετικέτα>

<!doctype html public "-//IETF//DTD HTML//EN">
<HTML>
<HEAD>
<TITLE>Τίτλος της σελίδας</title>

<META NAME="GENERATOR" CONTENT="thread.pl">
<META NAME="AUTHOR" CONTENT="Diomidis Spinellis">
<META HTTP-EQUIV="Content-type" CONTENT="text/html; charset=ISO-8859-7">
<LINK REV="made" HREF="mailto:dspin@aegean.gr"> 
<LINK REL="ToC" href="./web/index.htm">
<LINK REV="Subdocument" href="./web/index.htm">
<LINK REL="previous" href="./web/http.htm">
<LINK REL="next" href="./web/cgi.htm">

</HEAD>

<BODY> <H1>Επικεφαλίδα πρώτου επιπέδου</H1><HR>
Κείμενο που περιέχει ένα σημείο κατάληξης υπερκειμένου
<a name="G42"> (<em>με έντονο κείμενο</em>)</a> 
και μια λίστα:
<ul>
<li> στοιχείο 1
<li> στοιχείο 2
</ul>

<p>
Νέα παράγραφος με ένωση υπερκειμένου στο
<A HREF="http://www.aegean.gr">Πανεπιστήμιο Αιγαίου</A>

<HR>
</BODY>

</HTML>

Private Sub Form_Load()
    mcictrl.Notify = False
    mcictrl.Shareable = False
    mcictrl.DeviceType = "AVIVideo"
    mcictrl.filename = "C:\Program Files\Microsoft Office\Clipart\MMedia\globe.AVI"
    mcictrl.Command = "Open"
    mcictrl.Wait = True
    mcictrl.Command = "Play"
    mcictrl.Command = "Close"
    mcictrl.filename = "C:\Program Files\Microsoft Office\Clipart\MMedia\sonata8.wav"
    mcictrl.Command = "Open"
    mcictrl.Wait = True
    mcictrl.Command = "Play"
    mcictrl.Wait = True
    mcictrl.Command = "Close"
End Sub

Private Sub Command1_Click()
With Form1.MSChart1
        ' Displays a 3d chart with 8 columns and 8 rows
        .chartType = VtChChartType3dArea
        .ColumnCount = 8
        .ShowLegend = False
        .RowCount = 8
        For Column = 1 To 8
            For Row = 1 To 8
                .Column = Column
                .Row = Row
                .Data = Row * 10 + Column * 3 + Rnd * 40
            Next Row
        Next Column
    End With
End Sub

open "numbers.txt" for output as #1
for i = 1 to 10
	write #1, i, string(i, ".")
next i
close #1

open "numbers.txt" for input as #1
do while not eof(1)
	input #1, num, s
	msgbox str(num) + s
loop
close #1

Type Record
	ID As Integer
	Name As String * 20
End Type

Dim MyRecord As Record
Open "TESTFILE.dat" For Random As #1 Len = Len(MyRecord)
Put #1, 5, MyRecord
Get #1, 5, MyRecord
Close #1

on error resume next
open "names.txt" for input as #1
if err <> 0 then
	msgbox "names.txt: " + err.description
	exit sub
end if
on error goto 0

Sub main()
    Dim xl As Excel.Application
    Dim ws As Excel.Worksheet
    Dim wb As Excel.Workbook
    Dim regions(4, 1) As String
    
    regions(0, 0) = "Europe"
    regions(1, 0) = "Americas"
    regions(2, 0) = "Asia"
    regions(3, 0) = "Africa"
    
    
    Set xl = New Excel.Application
    xl.Visible = True
    Set wb = xl.Workbooks.Add
    Set ws = wb.Worksheets(1)
    
    ws.Range("A2:A5") = regions
    For i = 2 To 5
        ws.Range("B" & Format(i)).Value = i * 110 * Rnd
    Next i
    
    Dim chart As Excel.chart
    Dim rn As Range
    
    Set rn = ws.Range("A1:B5")
    
    Set chart = wb.Charts.Add
    chart.ChartWizard rn, xl3DPie, 7, xlColumns, 1, 1, 1, "Sales by area", "Areas", "Sales"
End Sub

Sub main()
    Dim wd As Word.Application
    Dim doc As Word.Document
    
    Set wd = New Word.Application
    wd.Visible = True
    Set doc = Word.Documents.Add
    
    ' Insert title date and items
    Dim r As Word.Range
    Set r = doc.Paragraphs(1).Range
    r.InsertAfter ("Replacement Part Order")
    r.InsertParagraphAfter
    r.InsertAfter ("Date:" & Date)
    r.InsertParagraphAfter
    r.InsertAfter ("Please dispatch the following parts:")
    r.InsertParagraphAfter
    r.InsertParagraphAfter
    ' 7 random parts
    For i = 1 To 7
        r.InsertAfter Str(i) + ". Part code " + Format(Int(Rnd * 10000 + 1), "000000") + " qty " + Str(Int(Rnd * 100 + 1))
        r.InsertParagraphAfter
    Next i
    
    r.Paragraphs(1).Alignment = wdAlignParagraphCenter
    
    ' Format title
    Dim pr As Word.Range
    Set r = doc.Paragraphs(1).Range
    Set pr = doc.Range(r.Start, r.End)
    pr.Font.Bold = True
    pr.Font.Size = 14
    pr.Font.Name = "Arial"
End Sub

Sub main()
    Dim Ammt As Double
    
    Ammt = InputBox("Δώστε την αρχική τιμή")
    MsgBox "Η τιμή χωρίς το ΦΠΑ είναι " + Str(Ammt / 1.18)
End Sub

Sub main()
    Dim Ammt As Double
    Dim nyears As Integer
    Dim interest As Double
    Dim i As Integer
    
    Ammt = InputBox("Δώστε το αρxικό ποσό")
    nyears = InputBox("Δώστε τον αριθμό των περιόδων")
    i = 0
    Do While i < nyears
        interest = InputBox("Δώστε επιτόκιο για την περίοδο " + str(i + 1))
        Ammt = Ammt * (1 + interest / 100)
        i = i + 1
    Loop
    MsgBox "Το τελικό ποσό είναι " + Str(Ammt)
End Sub